RF avec TX-SAW-MID-5V/RX-4MM5/F et picaxe 14M2

D

ddaweb

New Member
Bonjour à tous,

Je voudrait faire évoluer mon chrono d'Agility avec une transmission RF au lieu d'un câble actuellement pour les cellules.
Pour cela j'utilise les modules suivants :
- TX : Emetteur AM ASK 433,92 TX-SAW-MID-5V
- RX : Récepteur AM ASK 433,92 RX-4MM5/F

Je me suis basé sur le projet d'Electromag1 .
Comme batterie, j'ai choisit de travailler en LI-PO de 3.7v 4000mA et des step up pour convertir en 5v (Picaxe) et 12v (cellules).

Avant de tout acheter, comme j'avais les picaxes, je l'ai testé juste avec un fil de liaison à la place des 2 modules : tout était OK -> j’achète donc tout le matériel et réalise les plaquettes.
En RF, le picaxe ne réagit pas lors d'une transmission de données, si je mets un fil, cela fonctionne correctement et le chrono réagit également lorsqu'il est raccordé au récepteur.

J'utilise la fonction rfout/rfin : un 14M2 comme récepteur (pin B.5) et 18M2+ comme émetteur sur la pin B.4 (besoin de plus d'entrées pour d'autres commandes).

Je n'ai malheureusement pas d'oscilloscope pour mesurer le signal à l'entrée au picaxe, mais au voltmètre j'ai une variation de tension à la transmission, il se passe donc bien quelque chose.
Sur la broche RSSI du module, je constate également une variation de tension si j'active l'AGC.

Ces modules ne seraient pas compatibles avec le protocole Manchester ?

Si quelqu'un a une idée ou des modules qui fonctionneraient, je suis preneur.
D'avance merci pour votre aide.
DDA
 
ddaweb said:
Bonjour à tous,

Je voudrait faire évoluer mon chrono d'Agility avec une transmission RF au lieu d'un câble actuellement pour les cellules.
Pour cela j'utilise les modules suivants :
- TX : Emetteur AM ASK 433,92 TX-SAW-MID-5V
- RX : Récepteur AM ASK 433,92 RX-4MM5/F

Je me suis basé sur le projet d'Electromag1 .
Comme batterie, j'ai choisit de travailler en LI-PO de 3.7v 4000mA et des step up pour convertir en 5v (Picaxe) et 12v (cellules).

Avant de tout acheter, comme j'avais les picaxes, je l'ai testé juste avec un fil de liaison à la place des 2 modules : tout était OK -> j’achète donc tout le matériel et réalise les plaquettes.
En RF, le picaxe ne réagit pas lors d'une transmission de données, si je mets un fil, cela fonctionne correctement et le chrono réagit également lorsqu'il est raccordé au récepteur.

J'utilise la fonction rfout/rfin : un 14M2 comme récepteur (pin B.5) et 18M2+ comme émetteur sur la pin B.4 (besoin de plus d'entrées pour d'autres commandes).

Je n'ai malheureusement pas d'oscilloscope pour mesurer le signal à l'entrée au picaxe, mais au voltmètre j'ai une variation de tension à la transmission, il se passe donc bien quelque chose.
Sur la broche RSSI du module, je constate également une variation de tension si j'active l'AGC.

Ces modules ne seraient pas compatibles avec le protocole Manchester ?

Si quelqu'un a une idée ou des modules qui fonctionneraient, je suis preneur.
D'avance merci pour votre aide.
DDA
Click to expand...
Bonjour,
MGU ou Mag1....c'est pareil
Les modules TX RX sont de qualité reconnue et le protocole Manchester ne dépend pas d'eux.
En 433 MHz, les antennes ont une longueur de 17cm.
Pour donner un avis, il faudrait le schéma du montage. En cas de besoin, une application simple sur cette page:

Fabriquer ses circuits imprimés

Fabriquer ses circuits imprimés avec la méthode perchlorure ou la méthode acide chloridrique et eau oxygénée
electromag1.wifeo.com
Et il faudrait aussi les codes, après, on voit.
Si le problème est uniquement la transmission HF, on devrait y arriver.
Les docs:
Sinon, j'ai eu de bons résultats avec ces modules:

HF WL101/102

Bienvenue sur la page hf-wl101102 de electromag1
electromag1.wifeo.com

MM
 
Last edited:
Bonsoir MGU,

Oui je savais que tu étais Mag1 ;)
Tu m'as également bien aidé pour mon chrono, pour te rafraichir la mémoire, il est programmable 1 ou 2 barrière et 1>2 ou 2>1 via interrupteurs (je vais rechercher le post si tu veux)

C'est uniquement RF, si je fais un pont entre RX et TX cela fonctionne.

Pour la grandeur de l'antenne, c'est bizarre, la doc du RX dit une antenne fouet de 16,5mm :

Antenna​

  1. A whip antenna, 16.5mm long and approximately 1 mm dia, brass or copper wire made, must be connected to the RF input of the receiver.
Doc en français :

Antenne​

  1. Une antenne fouet, de 16.5 mm de long et d'environ 1 mm de diamètre, en fil de laiton ou de cuivre, doit être connectée à l'entrée RF du récepteur.
EDIT : c'est +/- ce qu'il y a sur les modules Zigby


Les schéma sont fait, je les joins.
 

Attachments

  • Emetteur.png
    Emetteur.png
    122.9 KB · Views: 11
  • Recepteur.png
    Recepteur.png
    73.3 KB · Views: 11
Last edited:
Le code pour l'émetteur :

Rich (BB code): 
; MODULE EMETTEUR CHRONO
; Debut projet : 13/02/2025
; Source depart : http://electromag1.wifeo.com/chrono-agility.php

; 2 modes possible, l'un OU l'autre en fonction de B.3 :
;     -> Confifuration globale de l'emetteur :
;          - 5 jumps de configuration au 0V par defaut
;               B.0 et B.1 : l'adresse du chrono (4 chronos possible en meme temps : plusieurs terrains)
;               B.2 : active le bouton Start/Stop sur la barriere uniquement
;               B.3 : determine le mode de fonctionnement -> barriere OU AutoStart
;               B.7 : determine le nr de la barriere -> 1 ou 2
;          - 15/02/2025 : Si modification d'un jump de configuration -> reinitialisation de l'emetteur pour la nouvelle config
;     -> 1. Mode barrieres : B.3 au 0V
;          - Interrupt actif sur la barriere pour le Start -> C.0 = barriere
;          - B.2 permet d'avoir un BP Start/Stop pour commander le chrono (identique START/STOP sur le chrono lui-meme), TX = "S"
;          - 2 leds : etat de la barriere (B.5) + cmd START/STOP active (B.6)
;          - TX barriere en alarme (TX = "B") ET barriere au repos (TX = "R") pour le status au chrono (recepteur : latch etat)
;          - commandes : C.0 = barriere et C.7 = Start/Stop
;     -> 2. Mode juge : B.3 au V+
;          - Bouton pour les Juges, permet d'activer le demarrage automatique retarde de 15'' (ou valeur programmee au chrono) lorsqu'il siffle
;          - Commande : C.6, BP Auto Start sur le chrono (recepteur : pulse), TX = "A"
;          - 1 led : BP actif (B.6)

#picaxe 18M2
symbol adresse1=pinB.0        ; adresse binaire sur B.0 et B.1
symbol adresse2=pinB.1        ; adresse binaire sur B.0 et B.1
symbol startstop=pinB.2        ; v+ = Start/Stop possible, uniquement en "mode barrierre"
symbol autostart=pinB.3        ; v+ = "mode juge" (BP juge) -> 0v = "mode barriere"
symbol RF=B.4            ; Commande RF
symbol ledbar=B.5            ; Led barriere active, uniquement en "mode barriere" : V+
symbol ledcmd=B.6            ; Led Start/Stop (B.3) ou AutoStart (B.2) suivant mode de fonctionnement B.2 ou B.3 : V+
symbol nrbar=pinB.7        ; Numero barriere : 0v = barriere 1 - V+ = barrierre 2
symbol cmdcell=pinC.0        ; Entree cellule 1 : uniquement en "mode barriere"
symbol ledtx=C.2            ; Led TX active : V+
symbol cmdstartstop=pinC.6    ; Cmd Start/Stop : uniquement en "mode barriere"
symbol cmdautostart=pinC.7    ; Cmd AutoStart : uniquement en "mode juge"
symbol txcellule=b11        ; Gestion TX barriere -> interrupt bloque si 1 cellule en alarme
symbol txautostart=b12        ; Gestion TX Start/Stop -> led reste allumee si pas de retour repos
symbol config=w10            ; Somme des entrees au demarrage
symbol config2=w11        ; Somme des entrees apres demarrage afin de detecter un changement
symbol barchrono=w12        ; Numero de la barriere pour le RF : 1 ou 2
symbol adressechrono=w13    ; Adresse du chrono pour le RF : 1 -> 4
pullup %10001111            ; Resistance au + pour B.0 -> B.3 et B.7 : adresse (B.0 et B.1) et mode de fonctionnement (B.2, B.3 et B.7)
; =============== Initialisation du programme
start:
high ledbar,ledcmd,ledtx            ; Allumer les leds pour test
adressechrono=1                    ; ----- Gestion adresse chrono
if adresse1=1 then
    adressechrono=1+adressechrono
end if
if adresse2=1 then
    adressechrono=2+adressechrono
end if
bintoascii adressechrono, b1,b2,b3,b4,b5    ; uniquement b5 utilise pour TX
barchrono=1                        ; ----- Gestion Nr barriere
if nrbar=1 then
    barchrono=2
endif
bintoascii barchrono, b6,b7,b8,b9,b10    ; uniquement b10 utilise pour TX
txautostart=0
txautostart=0
config=adresse1+adresse2+autostart+startstop+nrbar
pause 500
low ledbar,ledcmd,ledtx            ; Eteindre les leds
if autostart=0 then                ; ----- "mode barriere"
    SETINT %0,%1                ; Activation interrupt C.0 (barriere 1 ou 2) -> commande au 0V
    goto modebarriere
else                            ; ----- "mode juge" : AutoStart uniquement
    SETINT OFF
    goto modejuge
endif
; =============== Demarrage boucles
modebarriere:
    Do
        config2=adresse1+adresse2+autostart+startstop+nrbar                ; ----- Modification jump config
        if config<>config2 then
            goto start
        endif
        if startstop=1 then                                    ; ----- Start/Stop autorise
            if cmdstartstop=0 AND startstop=1 AND txautostart=0 then        ; Start/Stop autorise
                high ledtx,ledcmd
                rfout RF,("TX",b5,"S",b10,b5,"S",b10)                ; TX Start/Stop
                pause 50
                rfout RF,("TX",b5,"S",b10,b5,"S",b10)                ; 2me TX Start/Stop
                pause 50
                txautostart=1
                low ledtx
                pause 100
            else if cmdstartstop=1 AND startstop=1 AND txautostart=1 then    ; Reset commande Start/Stop
                txautostart=0
                low ledcmd
            endif
        endif
    loop
modejuge:
    Do
        config2=adresse1+adresse2+autostart+startstop+nrbar    ; ----- Modification jump config
        if config<>config2 then
            goto start
        endif
        if cmdautostart=0 AND txautostart=0 then            ; ----- Commande AutoStart
            high ledtx,ledcmd
            rfout RF,("TX",b5,"A",b10,b5,"A",b10)        ; TX Auto Start
            pause 50
            rfout RF,("TX",b5,"A",b10,b5,"A",b10)        ; 2me TX Auto Start
            pause 50
            txautostart=1
            low ledtx
            pause 100
        endif
        if cmdautostart=1 AND txautostart=1 then
            txautostart=0
            low ledcmd
        endif
    loop
interrupt:
    high ledtx
    if txcellule=0 then                            ; ----- Envoi une cellule active : barriere NOK
        rfout RF,("TX",b5,"B",b10,b5,"B",b10)            ; TX barriere active
        pause 50
        rfout RF,("TX",b5,"B",b10,b5,"B",b10)            ; 2me TX barriere active
        pause 50
        high ledbar
        txcellule=1
        SETINT %1,%1                            ; Activation interrupt C.0 etat haut (barriere 1 ou 2)
    else                                         ; ----- Envoi 2 cellules au repos : barriere OK
        rfout RF,("TX",b5,"R",b10,b5,"R",b10)            ; TX barriere au repos
        pause 50
        rfout RF,("TX",b5,"R",b10,b5,"R",b10)            ; 2me TX barriere au repos
        pause 50
        low ledbar,ledtx
        txcellule=0
        SETINT %0,%1                            ; Activation interrupt C.0 etat bas (barriere 1 ou 2)
    endif
    low ledtx
    pause 100
return
 
Pour le récepteur :

Rich (BB code): 
; MODULE RECEPTEUR CHRONO
; Debut projet : 15/02/2025
; Source depart : http://electromag1.wifeo.com/chrono-agility.php

#picaxe 14M2
symbol outbar1=B.1
symbol outbar2=B.2
symbol outstartstop=B.3
symbol outautostart=B.4

symbol adresse1=pinC.0
symbol adresse2=pinC.1
symbol ledtx=C.4

symbol adressechrono=w13    ; (w13) Adresse du chrono pour le RF : 1 -> 4

pullup %0000001100000000    ; Resistance au + pour C.0 et C.1 : adresse chrono
inputtype %000000100000        ; Mettre B.5 en mode Trigger de Schmitt pour decoder emetteur
; =============== Initialisation du programme
start:
high ledtx
adressechrono=1                            ; ----- Gestion adresse chrono
if adresse1=1 then
    adressechrono=1+adressechrono
end if
if adresse2=1 then
    adressechrono=2+adressechrono
end if
bintoascii adressechrono, b10,b11,b12,b13,b14        ; Code ASCII adresse chrono, uniquement b14 utilise
pause 500
low ledtx
; =============== Demarrage boucles
gestion:
    Do
        rfin B.5,b1,b2,b3,b4,b5,b6,b7,b8                ; ----- Gestion RF -> attente RX (bloque)
        high ledtx                                ; POUR TEST
        if b1="T" AND b2="X" AND b3=b14 then            ; ----- TX recu ET le nr chrono est le bon
            ;serout B.0, N4800_4,(b3,b5,b4,b12,b13,b14)    ; POUR CONTROLE TX avec Putty
            high ledtx
            if b4="B" OR b4="R" then                ; Commande barriere
                if b5="1" then                    ;      Barriere 1
                    if b4="B" then
                        low outbar1
                    else if b4="R" then
                        high outbar1
                    endif
                else if b5="2" then                ;      Barriere 2
                    if b4="B" then
                        low outbar2
                    else if b4="R" then
                        high outbar2
                    endif
                endif
                pause 150                        ; Problemes avec pause 100, reset ne se fait pas toujours
            else if b4="S" then                    ; Commande Start/Stop
                low outstartstop
                pause 400
                high outstartstop
            else if b4="A" then                    ; Commande AutoStart
                low outautostart
                pause 400
                high outautostart
            endif
            low ledtx
        endif
    loop
 
ddaweb said:
Pour le récepteur :

Rich (BB code): 
; MODULE RECEPTEUR CHRONO
; Debut projet : 15/02/2025
; Source depart : http://electromag1.wifeo.com/chrono-agility.php

#picaxe 14M2
symbol outbar1=B.1
symbol outbar2=B.2
symbol outstartstop=B.3
symbol outautostart=B.4

symbol adresse1=pinC.0
symbol adresse2=pinC.1
symbol ledtx=C.4

symbol adressechrono=w13    ; (w13) Adresse du chrono pour le RF : 1 -> 4

pullup %0000001100000000    ; Resistance au + pour C.0 et C.1 : adresse chrono
inputtype %000000100000        ; Mettre B.5 en mode Trigger de Schmitt pour decoder emetteur
; =============== Initialisation du programme
start:
high ledtx
adressechrono=1                            ; ----- Gestion adresse chrono
if adresse1=1 then
    adressechrono=1+adressechrono
end if
if adresse2=1 then
    adressechrono=2+adressechrono
end if
bintoascii adressechrono, b10,b11,b12,b13,b14        ; Code ASCII adresse chrono, uniquement b14 utilise
pause 500
low ledtx
; =============== Demarrage boucles
gestion:
    Do
        rfin B.5,b1,b2,b3,b4,b5,b6,b7,b8                ; ----- Gestion RF -> attente RX (bloque)
        high ledtx                                ; POUR TEST
        if b1="T" AND b2="X" AND b3=b14 then            ; ----- TX recu ET le nr chrono est le bon
            ;serout B.0, N4800_4,(b3,b5,b4,b12,b13,b14)    ; POUR CONTROLE TX avec Putty
            high ledtx
            if b4="B" OR b4="R" then                ; Commande barriere
                if b5="1" then                    ;      Barriere 1
                    if b4="B" then
                        low outbar1
                    else if b4="R" then
                        high outbar1
                    endif
                else if b5="2" then                ;      Barriere 2
                    if b4="B" then
                        low outbar2
                    else if b4="R" then
                        high outbar2
                    endif
                endif
                pause 150                        ; Problemes avec pause 100, reset ne se fait pas toujours
            else if b4="S" then                    ; Commande Start/Stop
                low outstartstop
                pause 400
                high outstartstop
            else if b4="A" then                    ; Commande AutoStart
                low outautostart
                pause 400
                high outautostart
            endif
            low ledtx
        endif
    loop
Click to expand...
Tout cela a l'air sérieux. Oui, 17 en gros, j'ai pas fait le calcul, va pour 16.5, j'ai vu une self sur le schéma,...utile ?
Et le 10 µF sur la broche 13 ? Normal ?
Si le problème est uniquement la transmission, je pense qu'il faut faire un essai avec un schéma et un programme de test très simple, avec l'essentiel.
 
Last edited:
Bon, avec ta doc :
- j'ai retiré le C de 10µF sur la pine 13
- j'ai retiré la self entre antenne et 0v
- placé des antennes de 17cm (il me semble que pour l'émetteur 16.5 mm est indiqué, 17 cm pour l'instant)

Maintenant cela fonctionne.

J'ai juste encore un soucis de timing si l'impulsion de la cellule est très courte, le récepteur ne traite pas le reset alors qu'il est transmit : je vois ma led TX clignoter 2 fois sur l'émetteur, mais 1 fois sur le récepteur ... s'il n'y a plus que cela comme soucis ... j'y regarde demain :p

Pour la self, dans la doc que j'avais, elle sert de protection contre les décharge électrostatique.
 
MGU said:
Tout cela a l'air sérieux. Oui, 17 en gros, j'ai pas fait le calcul, va pour 16.5, j'ai vu une self sur le schéma,...utile ?
Et le 10 µF sur la broche 13 ? Normal ?
Si le problème est uniquement la transmission, je pense qu'il faut faire un essai avec un schéma et un programme de test très simple, avec l'essentiel.
Click to expand...
Tu pourras remarquer un peu ta marque de fabrique dans la programmation, j'ai un peu suivit tes conseils lors de mes débuts avec le chrono lui-même et du Picaxe :whistle:

J'y ai trouvé un grand intérêt de mettre des noms logiques ... ce m'a bien servit lors de changement de pine de raccordement suite à des erreurs ... pas assez lu le manuel et utilisé des pines à mauvais escient.

EDIT : tu auras certainement remarqué qu'il n'y a pas de C de découplage d'alim au récepteur -> il se trouve sur l'alim du chrono :)
 
ddaweb said:
EDIT : tu auras certainement remarqué qu'il n'y a pas de C de découplage d'alim au récepteur -> il se trouve sur l'alim du chrono:)
Click to expand...
Il doit y avoir un condo un 100nF céramique au plus près des broches alim de chaque µC.
Comment fais tu les PCB ?
MM
 
Ma joie a été de courte durée, je ne sais pas aller plus loin que 2m, après le récepteur ne reçoit plus rien :)
Je vais essayer de trouver des fils rigides en cuivre de 1 mm² pour les antennes, ici j'ai torsader légèrement et souder finement 2 fils de 0.5mm² pas en cuivre.

Pour le PCB : ce sont des plaquettes de test pour le RF, le chrono a été fait chez JLCPCB

Côté programme, je vais devoir tenir compte que mes cellules sont très rapides, elles détectent le passage d'un double mètre à 1m : je vais regarder à retarder le reset dans l'interrupt avant envoi.

Si j'en met un C sur le récepteur, il sera en parallèle avec celui sur le chrono, la valeur totale ne va-elle pas doubler ?
En mettre un n'est pas un soucis !

NB : la plaquette brune sur le chrono a été une évolution car le switch du powerbank vers le 220v (alimentation classique) provoquait un reset du chrono, j'ai trouvé un switcher électronique et je travaille maintenant avec un chargeur GSM + powerbank -> j'ai récupéré les contact d'alimention du PCB du chrono. La R de puissance est pour maintenir le powerbank ouvert
 

Attachments

  • RF.png
    RF.png
    1,001.1 KB · Views: 8
  • chrono.png
    chrono.png
    902.8 KB · Views: 8
Last edited:
ddaweb said:
Ma joie a été de courte durée, je ne sais pas aller plus loin que 2m, après le récepteur ne reçoit plus rien :)
Je vais essayer de trouver des fils rigides en cuivre de 1 mm² pour les antennes, ici j'ai torsader légèrement et souder finement 2 fils de 0.5mm² pas en cuivre.

Pour le PCB : ce sont des plaquettes de test pour le RF, le chrono a été fait chez JLCPCB

Côté programme, je vais devoir tenir compte que mes cellules sont très rapides, elles détectent le passage d'un double mètre à 1m : je vais regarder à retarder le reset dans l'interrupt avant envoi.

Si j'en met un sur le récepteur, il sera en parallèle avec celui sur le chrono, la valeur totale ne va-elle pas doubler ?
En mettre un n'est pas un soucis !
Click to expand...
Il n'y a aucun inconvénient à doubler les découplages, alim et µC.
Il faut se méfier énormément des plaques d'essai rapide, nid de mauvais contacts, de capa parasites etc.
J'ai été surpris par ces transmetteurs : http://electromag1.wifeo.com/hf-wl101102.php
Un essai ne coute pas très cher.
MM
 
Je suis assez d'accord avec les plaquettes de test, mais ce modèle m'a assez surpris, elles datent de plusieurs années et pas d'oxydation : les trous sont métallisés + pastilles sur le dessus ... elles ne sont pas données non plus.

J'aurais voulu avoir les modules RF pour notre concours du 20 avril ... je ne crois pas y arriver :(
Mais ce n'est pas grave en soit, avec les câbles cela fonctionne et de toute façon, je rend les barrières complètement compatible avec les 2 systèmes.

Je fais encore quelques essais et ensuite ta solution comme plan B, je devrais commander 2 émetteurs (2 kits certainement).
EDIT : je viens de voir que l'émetteur est en 3.6v max ... hummm une petite zéner sera nécessaire pour limiter la tension, la batterie >=3.7v, le reste en 5v et 12v
 
Last edited:
Un petit retour en arrière, le prototype de mon chrono qui m'a permis de faire tout le développement ... et il fonctionne toujours :)
Maintenant j'ai un boitier complet, récupération du chrono après modification de l'alimentation, c'est nettement plus facile !!
 

Attachments

  • prototype.png
    prototype.png
    888.3 KB · Views: 4
ddaweb said:
Je fais encore quelques essais et ensuite ta solution comme plan B, je devrais commander 2 émetteurs (2 kits certainement).
EDIT : je viens de voir que l'émetteur est en 3.6v max ... hummm une petite zéner sera nécessaire pour limiter la tension, la batterie >=3.7v, le reste en 5v et 12v
Click to expand...
Je ne connais pas la tension max de la batterie
Peut être un BAT41 en série...avec un découplage
Ou un régulateur 3V3 sur le 5V
MM
 
Last edited:
MGU said:
Je ne connais pas la tension max de la batterie
Peut être un BAT41 en série...avec un découplage
MM
Click to expand...
Je viens de la mesurer, après quelques heures de test hier soir : 4.02v
Même tension si j'active le PCB, mais sans les cellules : qui chutera certainement alors avec une conso de +/- 20-30 mA.
Une chute de tension de 0.6v ferait l'affaire, une simple 1N4001 ou 1N4148 (j'en ai un paquet en stock :)) ?
 
Côté timing, j'ai modifié la pause de 50 à 100 dans l'interrupt de l'émetteur et c'est déjà pas mal (à tester en profondeur) : le récepteur reçoit aussi le reset même avec des impulsions très courtes :

Code: 
interrupt:
    high ledtx
    if txcellule=0 then                            ; ----- Envoi une cellule active : barriere NOK
        rfout RF,("TX",b5,"B",b10,b5,"B",b10)            ; TX barriere active
        pause 100
        rfout RF,("TX",b5,"B",b10,b5,"B",b10)            ; 2me TX barriere active
        pause 100
        high ledbar
        txcellule=1
        SETINT %1,%1                            ; Activation interrupt C.0 etat haut (barriere 1 ou 2)
    else                                         ; ----- Envoi 2 cellules au repos : barriere OK
        rfout RF,("TX",b5,"R",b10,b5,"R",b10)            ; TX barriere au repos
        pause 100
        rfout RF,("TX",b5,"R",b10,b5,"R",b10)            ; 2me TX barriere au repos
        pause 100
        low ledbar,ledtx
        txcellule=0
        SETINT %0,%1                            ; Activation interrupt C.0 etat bas (barriere 1 ou 2)
    endif
    low ledtx
    pause 100
return

Je vais acheter des antennes, ce sera plus facile : j'espère que cela fonctionnera alors
Je souhaiterais pouvoir avoir +/- 30m de portée ... là, toute de suite, je ne suis qu'à 10 cm en ayant une pseudo antenne de 16.5mm à l'émetteur comme indiqué dans la doc :)
 
ddaweb said:
Côté timing, j'ai modifié la pause de 50 à 100 dans l'interrupt de l'émetteur et c'est déjà pas mal (à tester en profondeur) : le récepteur reçoit aussi le reset même avec des impulsions très courtes :

Code: 
interrupt:
    high ledtx
    if txcellule=0 then                            ; ----- Envoi une cellule active : barriere NOK
        rfout RF,("TX",b5,"B",b10,b5,"B",b10)            ; TX barriere active
        pause 100
        rfout RF,("TX",b5,"B",b10,b5,"B",b10)            ; 2me TX barriere active
        pause 100
        high ledbar
        txcellule=1
        SETINT %1,%1                            ; Activation interrupt C.0 etat haut (barriere 1 ou 2)
    else                                         ; ----- Envoi 2 cellules au repos : barriere OK
        rfout RF,("TX",b5,"R",b10,b5,"R",b10)            ; TX barriere au repos
        pause 100
        rfout RF,("TX",b5,"R",b10,b5,"R",b10)            ; 2me TX barriere au repos
        pause 100
        low ledbar,ledtx
        txcellule=0
        SETINT %0,%1                            ; Activation interrupt C.0 etat bas (barriere 1 ou 2)
    endif
    low ledtx
    pause 100
return

Je vais acheter des antennes, ce sera plus facile : j'espère que cela fonctionnera alors
Je souhaiterais pouvoir avoir +/- 30m de portée ... là, toute de suite, je ne suis qu'à 10 cm en ayant une pseudo antenne de 16.5mm à l'émetteur comme indiqué dans la doc :)
Click to expand...
Je pense que 30 m à vue devraient âtre facilement atteints avec les modules AUREL, mais je n'ai pas testé,
Les WL101 sont minuscules, comme les antennes tire bouchon fournies. Les antennes doivent avoir la même polarité (horizontale ou verticale, le meilleur rayonnement est vertical)
 
MGU said:
Je pense que 30 m à vue devraient âtre facilement atteints avec les modules AUREL, mais je n'ai pas testé,
Les WL101 sont minuscules, comme les antennes tire bouchon fournies. Les antennes doivent avoir la même polarité (horizontale ou verticale, le meilleur rayonnement est vertical)
Click to expand...
Le béaba des émissions, c'est verticale que je compte mettre les antennes, à voir si j'ai la hauteur suffisante dans le boitier du chrono, il est possible que je doive faire un angle (elle est vers l'arrière, côté terrain, sur la partie haute du boitier pupitre).
Pour les cellules, là pas de soucis avec le boitier G313M
Livraison mardi ou mercredi, j'ai hâte de les avoir ... surtout que cela fonctionne plus loin que 10 cm :)
 
Last edited:
MGU said:
Bonjour,
J'ai zappé #17 et les antennes .
Je pense que c'est très cher pour un petit morceau de cuivre enroulé
Investis plutôt dans les WL101, les antennes sont fournies.
Une doc assez complète de ces modules (voir la description), et le prix, 3,39 € port compris:
www.aliexpress.com

433Mhz RF Transmitter and Receiver Superheterodyne ASK 433 Mhz Module With Antenna For Arduino Uno Wireless Diy Kits - AliExpress 44

Smarter Shopping, Better Living! Aliexpress.com
www.aliexpress.com www.aliexpress.com
MM
Click to expand...
C'est cher ... oui, mais les modules Aurel je les ai et les PCB sont fait avec.
Si de doit acheter 2 kit + modifier le PCB, je ne sais pas si les antennes ne sont pas plus intéressantes dans le cas où cela fonctionne ... en plus je pourrai faire le 2 me chrono (j'ai toutes les pièces sans le RF et je compte maintenant faire le boitier).
Je vais récupérer l'afficheur OLED de Picaxe sur mon chrono de test et monter un afficheur avec ton projet du LCD 1602 (j'ai acheté ce qu'il faut :)).
Les AXE 133Y sont devenu exorbitants : + de 60 € !
 
ddaweb said:
C'est cher ... oui, mais les modules Aurel je les ai et les PCB sont fait avec.
Si de doit acheter 2 kit + modifier le PCB, je ne sais pas si les antennes ne sont pas plus intéressantes dans le cas où cela fonctionne ... en plus je pourrai faire le 2 me chrono (j'ai toutes les pièces sans le RF et je compte maintenant faire le boitier).
Je vais récupérer l'afficheur OLED de Picaxe sur mon chrono de test et monter un afficheur avec ton projet du LCD 1602 (j'ai acheté ce qu'il faut :)).
Les AXE 133Y sont devenu exorbitants : + de 60 € !
Click to expand...
Pour le LCD, j'ai mis à jour cette page, avec PCB JLCPCB:

LCD série 18M2

Bienvenue sur la page lcd-serie-18m2 de electromag1
electromag1.wifeo.com
code pour LCD série avec accentué français.
Les modules HF auraient intérêt à être déportés en haut d'un mat, avec une liaison +,-,data.
MM
 
C'est bien de ce projet que je parlais.
Tient, tu mets 2 R de 10k pour la programmation du 18M2 ? C'est une erreur ?
J'ai toujours placé une 22k à la sortie du picaxe et une 10k vers la masse sans le moindre soucis (aussi dans la doc) :unsure:

Malheureusement pour le RF, il sera dans le boitier qui sera sur le bas de la barrière de départ et arrivée (côté opposé du passage du chien, côté chien, il ne peut rien y avoir) ... je doute fortement que le juge accepte un mat, même si c'est idéal :) :)
Déjà que les haies ont une dimension bien définie dans le règlement des concours.
Maintenant le chrono est sur une table sur le terrain, donc +/- 70 cm du sol, cela ne devrait pas poser de problème majeur.

EDIT :
Tu sais si la plaquette série du AXE 133Y est compatible avec un LCD 1602 ? J'ai un afficheur OLED qui ne fonctionne plus (affiche des caractères qui ne correspondent pas à l'envoi, n'importe quoi), mais c'est plus que probablement l'afficheur, j'ai remplacé le 18M2 avec le code standard.
Sinon, je m’amuse à mesurer pine par pine, je n'ai pas encore pris la peine de le faire.
J'ai trouvé un afficheur OLED Winstar pour le remplacer, mais je doit commander pour min. 50€ :(
 

Attachments

  • pgm.png
    pgm.png
    24.6 KB · Views: 4
  • axe_133y.png
    axe_133y.png
    501.8 KB · Views: 4
Last edited:
ddaweb said:
Bonjour,
Click to expand...
La 10k n'est pas une erreur. Pour justifier, il faut faire un peu d'histoire.
A l'origine, les picaxes étaient programmés à partir des ports RS323 des PC avec 3 bouts de fils.
La norme était alors entre -3V et -25V pour un "1" et de +3V à +25V pour un "0". Les picaxes sont toujours adaptés à cette norme.
Pour limiter le courant avec ces tensions et protéger les diodes de clamp (protection interne des µC, la R de 22k était indispensable.
Une R est toujours utile si, les tensions alim du µC et les tensions de programmation sont différentes (alim µC 3V et usb 5V), mais 10k sont largement suffisants. Les valeurs de R utilisées dans les montages sont essentiellement 10k, 1k, et 390 pour les leds , on peut éviter l'achat de 10 R de 22k. En fait, si on utilise les 5V du cordon de programmation, cette R est inutile. Comme les picaxes ont gardé la logique d'origine, il faut maintenant un double inverseur sur les pulses générés par les convertisseurs modernes. Les cordons USB AXE027 intègrent cette inversion.
Le code sur le site n'est pas adapté aux OLED, (je n'utilise que des LCD chinois faible cout), il faut retourner au code original qui donne le choix entre les deux (il y a deux lignes avec une des deux en commentaire). Je vais l'ajouté en option sur le site.
Code: 
#picaxe 18M2
; ********************************************
; Note you must uncomment just one of these two options
; depending on whether you have an LCD or OLED module
#define use_OLED
;#define use_LCD
; ********************************************
L'adaptateur est indépendant du type d'afficheur .

Le boitier est en bas, ok, pas possible de placer un tout petit boitier contenant le petit module émetteur avec sa petite antenne un peu plus haut ? Dans l'ancien projet Agility, je plaçais un flash sur la barrière pour visualiser l'émission du signal start .
MM
 
Last edited:
Bonjour MGU,

Merci pour ce petit cours d'histoire, dans mon cas, je vais alors garder les 22k car j'ai encore un port série sur mon PC fixe et j'ai placé la DB9 dans un slot arrière du PC :)
J'ai aussi un adaptateur USB-série pour le portable, mais en général je travaille sur le fixe, mieux équipé, dont 2 écrans.

Pour le OLED, j'ai en effet utilisé le code d'origine pour le 18M2.
Je vais donc dé-souder l'interface série de l'afficheur et y adjoindre un pot de 10 k pour le contraste.

Pour les produits chinois, je n'adhère que très peu, peu chers (pas toujours fiables si pure chinois), mais un gros impact écologique ... mais cela reste un choix personnel :)
J'y fait parfois appel, que dans de rares occasions : produit n'existe pas en Europe, la différence de prix est vraiment trop grande avec l'Europe.
Je sais que beaucoup de produits viennent de là, mais souvent importés en grande quantité (fabriqué suivant les normes de l'acheteur), pas un paquet pour 1 personne.
 
ddaweb said:
, je vais alors garder les 22k car j'ai encore un port série sur mon PC fixe et j'ai placé la DB9 dans un slot arrière du PC :)
J'ai aussi un adaptateur USB-série pour le portable, mais en général je travaille sur le fixe, mieux équipé, dont 2 écrans.

Ok, si yu as encore un DB9, c'est 22k et pas d'inverseur, comme au bon vieux temps...Je vais aussi le préciser ou revenir au 22k, on sait jamais...
Click to expand...
MM
 
J'ai eu du mal à dé-souder le module série l'afficheur OLED, mais à force de persévérance et pince coupante j'y suis arrivé :)
Vu que j'ai un peu mal traité le PCB avec de multiples coup de fer à souder, j'ai contrôlé toutes les pines avec ton plan ... juste la led de rétroéclairage que j'ai mise sur l'alim directement + carte enfichée maintenant, comme toi.
J'ai tout de même remis le pgm original car le chrono du club a un afficheur OLED avec ce pgm (et sans caractère accentué) ... cela m'évitera d'avoir des différences en cas de développement ultérieur.
L'afficheur n'est pas compatible avec mon support, mais j'ai mis que 2 vis et cela me convient pour le chrono de test, si c'était celui du club j'aurais rusé pour faire mieux :)

RMQ : L'afficheur OLED est nettement plus visible, surtout au soleil !

NB : j'ai fait le test avec le convertisseur USB-Sérial, je n'ai pas de soucis avec la 22k (elle est sur tous mes PCB)
 

Attachments

  • Chrono_test.png
    Chrono_test.png
    282.2 KB · Views: 4
Pour la 2me version et donc pour le club, j'ai amélioré l'esthétique.
Tu verras la différence d'afficheur :)
Pour les leds, les trous sont juste percées à son diamètre et à raz du boitier (collées à la colle à chaud), c'est le collant qui étanchéise.
 

Attachments

  • Chrono_club.png
    Chrono_club.png
    410.7 KB · Views: 4
  • Chrono_club_arrière.png
    Chrono_club_arrière.png
    242.7 KB · Views: 5
Last edited:
ddaweb said:
Pour la 2me version et donc pour le club, j'ai amélioré l'esthétique.
Tu verras la différence d'afficheur :)
Pour les leds, les trous sont juste percées à son diamètre et à raz du boitier (collées à la colle à chaud), c'est le collant qui étanchéise.
Click to expand...
Bonjour,
Le OLED est effectivement plus lisible.
Je ne sais pas quel budget tu atteints avec cette réalisation, mais il y a de la demande, et vu les prix pratiqués dans le commerce, tu pourrais en monter quelques uns. JLCPCB fournit 5 PCB par commande
MM
 
Je dois avouer qu'il n'est pas donné en l'état, je n'ai pas encore refait le compte avec les prix actuels, mais je suis aux alentours de 250 € avec le boitier extérieurs des juges (il peuvent voir l'état du chrono avec 2 leds de haute luminosité et donner le coup d'envoi lorsque le chrono est prêt) et le boitier de raccordement des barrières (en RF, ce n'est plus utile) ... sans main d'oeuvre, petit matériel additionnel et RF.
La partie électronique n'est pas très chère (+/- 70 €), ce sont les composants du boitier qui font monter le prix.
Il faut y ajouter les cellules, pour en avoir de très bonne qualité, il faut au moins 90 €/cellules : nous avons récupéré un vieux chrono avec 2x 2 cellules.
Avec nos cellules de très bonne qualité, les quelques fois qu'il a fonctionné en concours, je n'ai eu qu'un seul chien qui n'a pas été détecté ... bon, il a sauté au dessus des cellules aussi :) :)

La plaquette du chrono je l'ai faites chez JLCPCB, mais je me demande si je ne vais pas modifier la partie alim avec une batterie LI-PO comme l'émetteur RF : la partie alim devrait approximativement revenir au même prix, mais plus besoin d'acheter un powerbank -> je peux couper l'alim de la plaquette global, cela a été prévu à la conception (ex. : son remplacement en cas de problème).
La plaquette JLCPCB reprenait : l'alim, le chrono, la commande du boitier des juges et l'afficheur extérieur, je dois couper les différents éléments.
Pour l'instant, il tient plus de 12h avec un petit powerbank de 2700 mAh, avec 4000mAh cela devrait tenir 1 WE ... à voir avec le RF.

En fait, je n'ai jamais pensé à le commercialiser, je l'ai réalisé uniquement pour m'amuser, en ayant peut-être été trop loin pour certaines choses :)

Mes cellules sont en NPN, mais je sais facilement les modifier en PNP, j'y avais regardé à l'époque : de mémoire, il faut remplacer le BC557 par un BC547 et le souder dans l'autre sens.

On peux aussi diminuer le prix en le faisant plus basique, sans certains luxes, en retirant :
- le switch pour inverser le sens des barrières : il faudra monter physiquement les barrières correctement
- l'AutoStart : 1 BP en moins, pour l'instant utilisé qu'au championnat du monde, quand je l'ai ajouté, ils parlaient de le faire aussi durant les concours
- la possibilité de mettre un chargeur GSM et un powerbank en secours : juste un des 2 (ex. powerbank) = le switch électronique,1 connexion et 1 fusible en moins (et quelques petits composants de la plaquette brune au #10)
- le boitier extérieur des juges : +/- 20 € + les 2 leds de rappel sur le chrono
- la possibilité de mettre un grand afficheur extérieur (je l'ai fait, il fera son premier test grandeur nature ce 20 avril) : 1 connecteur en moins

EDIT : toute ma réalisation est née de ton projet de chrono d'Agility, j'ai, ensuite, lu tout le post sur le forum, c'était assez marrant de voir l'évolution, les soucis rencontrés et les solutions apportées pour arriver à une fin fonctionnelle ... je tiens à te remercier de suivre également mon projet et pour ton aide.
As-tu eu des nouvelles de ce chrono ?
 

Attachments

  • Chrono_juges.png
    Chrono_juges.png
    588.6 KB · Views: 5
  • JLCPCB.png
    JLCPCB.png
    338.9 KB · Views: 5
Last edited:
Pour le chrono original, j'ai eu un contact du CLUB SPORTIF CANIN SEDANAIS 0643519067.
Connais tu ce club ?
MM
 
En parlant d'une précision beaucoup plus précise, il y a longtemps que je penses à un autre système pour le chrono :)

Le principe de base est assez simple, utilisé sur un chrono professionnel de haute précision :
- les barrières ont chacune une horloge synchronisée sur une horloge externe (devra être resynchronisé régulièrement pour éviter une trop grande déviation) : un realtime
- au passage du chien, la barrière envoie le microtime du moment ... on s'en fou donc de la latence pour l'envoi
- le chrono calcule simplement la différence du microtime entre l'arrivée et le départ, ce qui donne le temps du chien et on le met à 1/100

Je n'ai pas encore vraiment trouvé des éléments pouvant le faire
 
Last edited:
ddaweb said:
Haaa c'est en France, moi je suis en Belgique, tout près de Bruxelles :)
Non je ne connais pas ce club.
Click to expand...
Ils m'avaient contacté, ce sont apparemment eux qui ont récupéré le chrono monté par "le belge", qui a abandonné le club, je ne sais pas dans quel état il est maintenant.
Ils avaient dépenser pas mal d'argent pour essayer de le remettre en état et étaient près à investir encore 400€ .
Tu as le n° de téléphone, si tu es disponible .... entre passionnés...
Voici le message laissé sur mon site, datant de janvier 2024
bonjour j ai vu sur le site que vous pouvez fabriquer un chrono pour 400 euros serait il possible qu'une personne puisse me contacter pour en parler
sport canin sedanais dans les ARDENNES AU PLAISIR DE VOUS ENTENDRE MERCI
MR DAPREMONT LIONEL 0651439067
Click to expand...
MM
 
MGU said:
Bonjour,
Le OLED est effectivement plus lisible.
Je ne sais pas quel budget tu atteints avec cette réalisation, mais il y a de la demande, et vu les prix pratiqués dans le commerce, tu pourrais en monter quelques uns. JLCPCB fournit 5 PCB par commande
MM
Click to expand...
Il y a aussi des LCD blanc sur fond noir, peut être une alternative moins chère:
www.aliexpress.com

1Lot 5V 2004 LCD Module VA Black Color 20X4 HD44780 ST7066 EQV Chip Parallel 2004A Display IIC I2C Port - AliExpress 502

Smarter Shopping, Better Living! Aliexpress.com
www.aliexpress.com www.aliexpress.com
 
Bonsoir MGU,

MGU said:
bonjour j ai vu sur le site que vous pouvez fabriquer un chrono pour 400 euros serait il possible qu'une personne puisse me contacter pour en parler
sport canin sedanais dans les ARDENNES AU PLAISIR DE VOUS ENTENDRE MERCI
MR DAPREMONT LIONEL 0651439067

MM
Click to expand...
C'est via un message privé ?
Cela fait plus d'un an, tenter une approche par mail serait mieux, il n'est peut-être même plus au club : les membres, ça vient, ça va :)

Pour le RF : bon, ben, c'est un peu bof, déçu -> antenne presque complètement déroulé et droite, au mieux j'ai 10-12m.
J'ai essayé avec et sans AGC sur le récepteur.
Côté programme j'ai des timing à modifier, mais aujourd'hui je ne vais rien faire, grosse déprime ...
Pour les tests, je ne me basais pas vraiment sur le résultat du chrono vu le fine tuning à faire dans le pgm, mais de la led de réception (enfin traitement du signal correct du rfin/rfout : ledtx dans le pgm).

Il se pourrait que j'ai oublié de faire qque chose en hardware ?

Tu as utilisé quel type d'antenne pour le projet du Belge ? ... il me semble une antenne style wifi ?
 
ddaweb said:
Bonsoir MGU,

C'est via un message privé ?
Cela fait plus d'un an, tenter une approche par mail serait mieux, il n'est peut-être même plus au club : les membres, ça vient, ça va :)
Il se pourrait que j'ai oublié de faire qque chose en hardware ?
Tu as utilisé quel type d'antenne pour le projet du Belge ? ... il me semble une antenne style wifi ?
Click to expand...
Bonsoir,
Le contact était via le livre d'or. Je vais rechercher un mail.
Je n"ai pas d'expérience sur les modules AUREL, j'ai été déçu par des modules similaires.
Les liens vers les E/R utilisés par le belge ne fonctionnent plus (je vais les supprimer).
Au début, l'antenne était gravée sur le PCB, elle a sans doute évolué.
Après l'antenne 1/4 d'onde (17 cm), il y a le dipôle, deux brins de 17 cm alignés (à l'horizontal ou vertical), un brin à l'antenne, l'autre à la masse avec coaxial 50 ohm, puis, les antennes à plan de masse (3 brins masse vers le bas à 45 °), etc il y a de la doc sur internet.
Je ne reparle plus des WL101, tu n'en vaux pas, dommage...
MM
 
MGU said:
Je ne reparle plus des WL101, tu n'en vaux pas, dommage...
MM
Click to expand...
T'inquiète, je les garde comme plan C (oui, bon, j'ai reculé d'une lettre :)), ce sera après le concours.
Pour le mail, envoie le par MP.

Avec tes modules, as-tu fait des tests de distance dans un boitier ?

Pour l'instant je suis parti sur la partie qui fait défaut en plan B : l'antenne -> j'ai commandé un système assez pratique à mettre dans un boitier, une antenne à coller avec un gain de 6dbi (8 sur la pub) qui rentre dans mes boitiers ... ensuite je ne m'acharne plus avec le module Aurel.
D'ici ce WE je devrais l'avoir ... il ne me reste plus beaucoup de temps pour achever le RF avant le concours, sinon on tirera les câbles.
Dès que je suis dans la zone de réception optimale (max. 8 à 10m), cela fonctionne presque très bien, comme je l'ai dit, du timing à ajuster car quand je vais trop vite ça coïnce un peu :(

EDIT : si je n'arrive pas à faire fonctionner le RF, je vais réutiliser la batterie et alimentations pour le mettre dans le chrono -> plus de powerbank externe ... tout ne sera pas perdu !!
 
Last edited:
J'ai un peu avancé dans la distance : +/- 16m sans problème avec les timing adaptés, le max. que je peux faire dans la maison, avec des briques recuites contenant du fer (la portée du Wifi pose problème d'ailleurs) :)
Bizarrement, l'émetteur est avec une antenne à coller et le récepteur avec une antenne spirale en cuivre légèrement agrandie (sur le PCB) et dans le chrono (il ne fonctionnait pas bien avec une antenne à coller, même pas 6 m).
J'ai une petite antenne de 5 cm à mettre à l'extérieur du boitier (+/- la même hauteur que la spirale) : je vais essayer si sur le terrain je ne fais pas mieux.
Sur la photo, en noir, la position de l'antenne dans le boitier, les 2 jeux de cellules à droite.
C'est à cette hauteur que j'obtiens les meilleurs résultats, si je monte ou descend de trop, la portée diminue :(
Je vais devoir trouver un système pour fixer le boitier sur la barrière dès que la hauteur est bien déterminée, si possible réglable.
 

Attachments

  • recepteur_boitier.png
    recepteur_boitier.png
    564 KB · Views: 5
Last edited:
You must log in or register to reply here.
Back
Top