Well, it's taken a little while coming but since I said I'd share to the others that have kindly helped me with my little project, here it is.
Constructive criticisms will be very much appreciated but please go gently on me since it's my first attempt at anything like this.
Basically what I've tried to build is a voltage regulator for use with a bike light system I've cobbled together. I took a couple of mr16 pond lights from B&Q added some handlebar mounts and a 18.5v Li-ion battery and although this works I thought I'd make it a little more sophisticated by adding a regulator. It comes with soft start, low battery warning, turbo mode (unregulated) and low and high regulated modes to flatten out the battery discharge curve thus providing longer runtime and consistent brightness.
In the end I went to the reactive system as suggested by Dippy (I think). When I got into it I just couldn't understand why I was so intent having feedback in the first place, it just wasn't necessary. I also found by experimentation that simply averaging ADC readings was the most reliable way of getting a stable voltage reading so no need for filtering (another advantage of measuring the battery as opposed to the bulb voltage).
Anyway, here's the code and circuit:
n.b. I can't help tinkering and modded the code (particularly the button stuff) and have yet to test it so I may have introduced a couple of errors in there.
Constructive criticisms will be very much appreciated but please go gently on me since it's my first attempt at anything like this.
Basically what I've tried to build is a voltage regulator for use with a bike light system I've cobbled together. I took a couple of mr16 pond lights from B&Q added some handlebar mounts and a 18.5v Li-ion battery and although this works I thought I'd make it a little more sophisticated by adding a regulator. It comes with soft start, low battery warning, turbo mode (unregulated) and low and high regulated modes to flatten out the battery discharge curve thus providing longer runtime and consistent brightness.
In the end I went to the reactive system as suggested by Dippy (I think). When I got into it I just couldn't understand why I was so intent having feedback in the first place, it just wasn't necessary. I also found by experimentation that simply averaging ADC readings was the most reliable way of getting a stable voltage reading so no need for filtering (another advantage of measuring the battery as opposed to the bulb voltage).
Anyway, here's the code and circuit:
n.b. I can't help tinkering and modded the code (particularly the button stuff) and have yet to test it so I may have introduced a couple of errors in there.
Code:
' Battery voltage measured over 10k leg of 10k/33k divider
' ADC resolution 256 over 0 -> 5v
' To calculate measured voltage = byte value * (5 / 256)
' To calulate battery voltage = measured voltage * (43/10)
' Assign lamp and battery settings
' To simplify the maths calculate target voltages as equivalent ADC values
symbol low_power = 107 ' 9v = 107
symbol high_power = 143 ' 12v = 143
symbol turbo_power = 255 ' max battery voltage = 255
symbol low_batt_voltage = 179 ' 15v
' Assign ports
symbol switch1 = pin3
symbol pwmport = 2
symbol battmonitor = 1
' Assign variables
symbol dutycycle = w0 ' b0, b1
symbol targetvoltage = w1 ' b2, b3
symbol battvoltage = w2 ' b4, b5
symbol power = b6
symbol button_repeat = b7
symbol tempvoltage = b8
symbol counter = b9
' Initialize
button_repeat = 0
power = 0
counter = 0
battvoltage = 0
main:
'button switch1, 1, 100, 10, button_repeat, 1, button_pressed
' This replacement switch code needs testing so timings and counts may need adjusting
if switch1 = 1 then
' debouce button
pause 5
do while switch1 = 1
button_repeat = button_repeat + 1 max 255
pause 5
loop
gosub button_pressed
button_repeat = 0
endif
' Don't do anything until we're turned on
if power = 0 then goto main
' Read battery voltage and average over 200 readings
readadc battmonitor, tempvoltage
if counter < 200 then
battvoltage = battvoltage + tempvoltage
counter = counter + 1
else
battvoltage = battvoltage / 200
' calculate and set the dutycycle
dutycycle = targetvoltage * 250 / battvoltage * 4 max 1000
pwmout pwmport, 249, dutycycle
' Perform low battery check
if battvoltage <= low_batt_voltage then
for counter = 0 to 2
pwmout pwmport, 249, 0
pause 20
pwmout pwmport, 249, dutycycle
pause 20
next
endif
' reset averaging vars
counter = 0
battvoltage = 0
endif
goto main
button_pressed:
' Check for button press length
select button_repeat
case > 100
' Turn off and reset vars
pwmout pwmport, 249, 0
power = 0
targetvoltage = 0
return
else
' Short press so carry on as normal
endselect
power = power + 1
select power
case 1 ' Soft start up to low power
readadc battmonitor, battvoltage
dutycycle = low_power * 200 / battvoltage * 5 max 1000
for targetvoltage = 0 to dutycycle
pwmout pwmport, 249, targetvoltage
pause 10
next
' Now we're warmed up step up to low power
power = 2
targetvoltage = low_power
case 2, 6
targetvoltage = low_power
' If we've got here cos power = 6 then we've been stepping back down
' from high power so reset power to the beginning of the cycle again
power = 2
case 3, 5
targetvoltage = high_power
case 4
targetvoltage = turbo_power
endselect
return
