(Résolu)Afficher température sur four électrique

C

chimere322

Senior Member
Bonjour a tous,
J'ai un four électrique de marque thomson dont le thermostat et un simple bilame qui était défectueux.
Je l'ai remplacé par un thermostat avec un bulbe et qui fonctionne a la perfection. Mon problème vient du fait que l'affichage du bouton des température n'est plus compatible.Pour y remédier, je souhaiterais y installer avec une sonde de température sur un afficheur genre max7219 et picaxe ou tm 1637
avec une sonde de température adapte au four. Je précise que c'est juste un affichage de température entre 50° et250° en fonction du thermostat du four je peu lire la température.En fait je veux juste lire la température de mon four.
Vous allez me dire pourquoi pas mettre un thermomètre dans la porte du four, oui mais j'ai envie d'un petit boitier qui m'affiche le température .J'ai 69 ans mais je reste un grand enfant et découvreur.
bien à vous et grand merci?
 
C

chimere322

Senior Member
MGU said:
Bonjour,
Je peux proposer une version avec thermocouple, picaxe et TM1637.
Ex avec un LCD: http://electromag1.wifeo.com/thermocouple-max31855-et-picaxe-08m2.php
Ou http://electromag1.wifeo.com/thermocouple-max6675-et-picaxe-08m2.php
MM
Click to expand...
MGU said:
Bonjour,
Je peux proposer une version avec thermocouple, picaxe et TM1637.
Ex avec un LCD: http://electromag1.wifeo.com/thermocouple-max31855-et-picaxe-08m2.php
Ou http://electromag1.wifeo.com/thermocouple-max6675-et-picaxe-08m2.php
MM
Click to expand...
Bonsoir Michel,
je suis tout oui a tes propos ,je dispose des 08M2, des 14 M2 etc.... et des afficheurs TM1637 ainsi que des max sur ton site. je travaille beaucoup avec Gotronic qui est pas loin de chez moi, enfin disons Grand ESt.
Comme tu as compris c'est simplement une in indication de température dur four en fonction du thermostat avec une sonde. D'ailleurs dans le paroi du four il y a un trou libre de 4mm.
 
C

chimere322

Senior Member
chimere322 said:
Bonsoir Michel,
je suis tout oui a tes propos ,je dispose des 08M2, des 14 M2 etc.... et des afficheurs TM1637 ainsi que des max sur ton site. je travaille beaucoup avec Gotronic qui est pas loin de chez moi, enfin disons Grand ESt.
Comme tu as compris c'est simplement une in indication de température dur four en fonction du thermostat avec une sonde. D'ailleurs dans le paroi du four il y a un trou libre de 4mm.
Click to expand...
J suis partant pour un petit boitier avec picaxe et TM 4chiffres ou autre avec sonde ou max 7 machin . Pour le circuit imprimé aucun soucis, je grave avec du persulfat de sodium .c'est plus cher que du perchlorure mais plus rapide et plus fin
 
M

MGU

Senior Member
Bon, partons avec un thermocouple,
par ex https://fr.aliexpress.com/item/1005006222174410.html?spm=a2g0o.productlist.main.3.3700mznGmznGr4&algo_pvid=bf8e957c-45f8-4521-8e5b-c9d3ac264837&algo_exp_id=bf8e957c-45f8-4521-8e5b-c9d3ac264837-1&pdp_npi=4@dis!EUR!6.30!0.99!!!48.55!7.60!@210385a817176148127696453e94e6!12000036346641898!sea!FR!2679328060!AC&curPageLogUid=CMTys5qMiXgT&utparam-url=scene:search|query_from:
Un TM1637 ;http://electromag1.wifeo.com/tm1637-base-de-programme.php
Il faut 5 pattes pour ces deux modules, un 08M2 peut être, si on ne prévoit pas de réglage extérieur.
MM
 
C

chimere322

Senior Member
MGU said:
Bon, partons avec un thermocouple,
par ex https://fr.aliexpress.com/item/1005006222174410.html?spm=a2g0o.productlist.main.3.3700mznGmznGr4&algo_pvid=bf8e957c-45f8-4521-8e5b-c9d3ac264837&algo_exp_id=bf8e957c-45f8-4521-8e5b-c9d3ac264837-1&pdp_npi=4@dis!EUR!6.30!0.99!!!48.55!7.60!@210385a817176148127696453e94e6!12000036346641898!sea!FR!2679328060!AC&curPageLogUid=CMTys5qMiXgT&utparam-url=scene:search|query_from:
Un TM1637 ;http://electromag1.wifeo.com/tm1637-base-de-programme.php
Il faut 5 pattes pour ces deux modules, un 08M2 peut être, si on ne prévoit pas de réglage extérieur.
MM
Click to expand...
Bonjour Michel,
Cela me convient parfaitement. Je précise qu'il n'y aura pas de réglage extérieur dans le genre température de consigne.
Le montage sera intégré dans un petit boitier accrocher au mur au dessus du four avec un inter marche/arrêt et alimenter par 3 piles AA. Je passe commande dans la foulée sur aliexpress.
Cela vas me permettre de voir la température exact après la préchauffe car j'ai déjà grillé pas mal de tarte.
Cordialement JC
 
C

chimere322

Senior Member
Après avoir fouillé dans mes stocks de composants je n'ai que des max 7219 en 4 ou 5 digits.
pas de tm1637.
 
M

MGU

Senior Member
Pour l'instant, pas de précipitation. Je vais faire quelques essais. J'hésite avec le MAX31855, plus précis.
fr.aliexpress.com

0.8￡ 91% de réduction|Capteur de température thermocouple de type Tech K, mesure de la température pour Ardu37, 0 800, Louvain, Prévention 31855 | AliExpress

Achetez malin, vivez mieux! Aliexpress.com
fr.aliexpress.com fr.aliexpress.com

Pour le TM1637:
fr.aliexpress.com

1.13￡ 4% de réduction|Module D'affichage Led Tm1637 Pour Arduino, 4 Chiffres, 7 Segments, 0.56 Pouces, Indicateur D'horloge, Module De Tube, Rouge, Bleu, Vert, Jaune, Blanc - Circuits Intégrés - AliExpress

Achetez malin, vivez mieux! Aliexpress.com
fr.aliexpress.com fr.aliexpress.com
Faut choisir la couleur
MM
 
C

chimere322

Senior Member
Bonsoir Michel,
comme précisé j'ai commandé sur https://fr.aliexpress.com/item/1005006222174410.html?spm=a2g0o.productlist.main.3.3700mznGmznGr4&algo_pvid=bf8e957c-45f8-4521-8e5b-c9d3ac264837&algo_exp_id=bf8e957c-45f8-4521-8e5b-c9d3ac264837-1&pdp_npi=4@dis!EUR!6.30!0.99!!!48.55!7.60!@210385a817176148127696453e94e6!12000036346641898!sea!FR!2679328060!AC&curPageLogUid=CMTys5qMiXgT&utparam-url=scene:search|query_from:

pour les afficheurs j'ai pas d'autre en stock; il vas falloir faire avec ce que j'ai comme sur ton site sois max 7219 ou lcd dem
 
M

MGU

Senior Member
PieM said:
Si on a pas envie de manier le fer à souder : Thermometre -30 + 800°
Click to expand...
Bonjour,
Il est vrai que cette solution est a envisager sérieusement, d'autant que pendant mes essais avec le MAX6675, l'eau bouillante plafonne à 75°C. Je vais essayer avec le MAX31855...
Et en couleurs:
fr.aliexpress.com

3.36￡ |Thermocouple industriel Therye.com 12V 30 ~ 800 de type K de haute température M6 XH B310 résistant d'appareil de contrôle de compteur de température numérique | AliExpress

Achetez malin, vivez mieux! Aliexpress.com
fr.aliexpress.com fr.aliexpress.com
MM
 
Last edited:
C

chimere322

Senior Member
Bonjour à tous,

Bon, finalement PieM à trouvé la bonne solution.

Pour Michel, vu que j'ai commandé le thermocouple je serais tout de même prêt a jouer du fer a souder sur 14M2 et
afficheur DEM 16209 pour me passer le temps.
 
M

MGU

Senior Member
Bonsoir,
Pour info, le thermomètre thermocouple est opérationnel.
Matériel:
un module MAX31855 (avec son TC type K)
un LCD 1602 (ou autre), utilisé en // 4 bits
un picaxe 14M2
Et c'est tout...
Dans l'eau bouillante, il monte à 100°C et avec un décapeur thermique à 400°C env
Ici, il mesure la t° ambiante
Détails suivent...
MM
26094
 
Last edited:
M

MGU

Senior Member
Le code:
Le copier-coller du forum est apparemment limité à 1000 caractères et n'est pas passé (j'ai pas compté).
Le revoila, en "manuel"
La mesure est limitée aux valeurs entières, postives et négatives (on sait jamais...)
La mesure de la t° interne est ignorée
Code: 
;lecture thermocouple par MAX31855 MM 09/06/24
;La broche SO va prendre successivement la valeur de chaque bit du registre.
; scanné poids fort en tête
;détection erreur "Pas de sonde"
;gamme mesure voir DS
#picaxe 14M2
#no_data      
;symbol RS  = B.0     ; 0 = Command 1 = Data
symbol E    = B.1     ; 0 = Idle 1 = Active
;symbol DB4 = B.2 ;
;symbol DB5 = B.3    ; Broches data LCD
;symbol DB6 = B.4 ;
;symbol DB7 = B.5 ;
symbol CLK=C.1    ; pulse horloge
symbol CSB=C.2    ;demande lecture  _____/
symbol SO=pinC.3  ;bit de donnée serial out
symbol def1=bit0    ;bit "erreur"
symbol rsbit=bit1    ;bit comm/data
symbol flag=bit2    ;passage par "erreur"
symbol cpt=b1        ;compteur
symbol cpt2=b2        ;boucle mesure
symbol car=b3        ;byte caractère
;      b4,b5,b6,b7    ;car bintoascii
symbol sig=b9        ;signe valeur
symbol varw=w13      ;var temporaire
symbol temptherm=w11 ;tempé thermocouple
symbol cumul=w10     
setfreq M4          
dirsB=%1111111 'défini les ports B en sorties
table 0,(51,50,40,12,6,1)        ;initialisation LCD 4 bits
table 10,("ERREUR")
table 20,("PAS DE SONDE")
table 40,("Temp=      ßC   ")
;*****************************
#macro spin(varw)        ;macro SPIIN
    varw = 0
    for cpt = 1 to 16
        varw=varw * 2 + SO  ;décalage à gauche + SO (0 ou 1)  
        pulsout CLK,1       ;pulse horloge   
    next cpt  
#endmacro
;***********************************
; Initialisation LCD *********
    for cpt=0 to 5
        readtable cpt,car      
        gosub CommInit
    next
;********************
    pause 500
    car=1 : gosub commB        ;raz écran
    car=192 : gosub commB    ;début ligne 2
        for cpt=40 to 56
            readtable cpt,car    ;texte mesure
            gosub dataB
        next     
    high CSB    ;première conversion
    cumul=0
    Do         ;boucle principale
        for cpt2=1 to 5    ;on fait 5 mesures
            do     ;boucle si erreur
                pause 100  
                low CSB            ;lecture registre          
                spin(temptherm)    ;exécution macro 16 premiers bits (poids fort en tête)              
                high CSB           ;nouvelle conversion          
                ;temptherm=%0000011001001100    ;test 100,75 °C              
                ;*****defaut **********************          
                def1=temptherm//2        ;isol bit défaut              
                if def1>0  then            ;erreur détectée
                    gosub erreur
                else
                    if flag=1 then                    ;on est passé par sub erreur
                        car=1 : gosub commB        ;raz écran
                        car=192 : gosub commB    ;début ligne 2
                        for cpt=40 to 56
                            readtable cpt,car        ;on réécrit le texte  
                            gosub dataB
                        next
                        flag=0
                    endif                  
                endif              
            loop while def1>0     ;sortie boucle "erreur" si def1=0
    ;**** temp thermocouple ******************************      
            sig=" "
            temptherm=temptherm/4    ;suppression des 2 derniers bits
            if temptherm>=$2000 then    ;test 1er bit des 14 bits pour valeur négative
                sig="-"
                temptherm = - temptherm  ;idem complément à 2 pour valeur "positive"    
            endif           
            temptherm=temptherm/4    ;suppression des décimales-> val entière
            temptherm=temptherm//4096    ;on garde les 12 derniers bits
            cumul=cumul+temptherm
        next cpt2
        cumul=cumul/5        ;moyenne sur 5 mesures
        bintoascii cumul,b4,b4,b5,b6,b7       
        car=197 :gosub commB
        for cpt= 0 to 4
            lookup cpt,(sig,b4,b5,b6,b7),car
            gosub dataB
        next  
        cumul=0
    loop
; Sub envoi vers LCD parallèle 4 bits *************
Comminit:
    pause 15 ; Delay 15mS
commB:        ; c'est une commande
    rsbit = 0
dataB:        ;c'est une donnée
    pinsB = car & $F0 / 4 | rsbit ; 4 bits poids fort
    pulsout E,1 ; pulse validation sur E
    pinsB = car & $0F * 4 | rsbit ; 4 bits poids faible
    pulsout E,1 ; pulse validation sur E
    rsbit = 1     ; donnée par défaut
    return
;**************************************************
erreur:
    car=1:gosub commB        ;effacement écran
    car=128: gosub commB    ;pos curseur
    for cpt=10 to 15
        readtable cpt,car    ;erreur
        gosub dataB
    next
   car=192 : gosub commB 
   for cpt= 20 to 31
        readtable cpt,car        ;pas de sonde
        gosub dataB
    next
   pause 1000
    flag=1
   return
 
Last edited:
C

chimere322

Senior Member
MGU said:
Le code:
Le copier-coller du forum est apparemment limité à 1000 caractères et n'est pas passé (j'ai pas compté).
Le revoila, en "manuel"
La mesure est limitée aux valeurs entières, postives et négatives (on sait jamais...)
La mesure de la t° interne est ignorée
Code: 
;lecture thermocouple par MAX31855 MM 09/06/24
;La broche SO va prendre successivement la valeur de chaque bit du registre.
; scanné poids fort en tête
;détection erreur "Pas de sonde"
;gamme mesure voir DS
#picaxe 14M2
#no_data     
;symbol RS  = B.0     ; 0 = Command 1 = Data
symbol E    = B.1     ; 0 = Idle 1 = Active
;symbol DB4 = B.2 ;
;symbol DB5 = B.3    ; Broches data LCD
;symbol DB6 = B.4 ;
;symbol DB7 = B.5 ;
symbol CLK=C.1    ; pulse horloge
symbol CSB=C.2    ;demande lecture  _____/
symbol SO=pinC.3  ;bit de donnée serial out
symbol def1=bit0    ;bit "erreur"
symbol rsbit=bit1    ;bit comm/data
symbol flag=bit2    ;passage par "erreur"
symbol cpt=b1        ;compteur
symbol cpt2=b2        ;boucle mesure
symbol car=b3        ;byte caractère
;      b4,b5,b6,b7    ;car bintoascii
symbol sig=b9        ;signe valeur
symbol varw=w13      ;var temporaire
symbol temptherm=w11 ;tempé thermocouple
symbol cumul=w10    
setfreq M4         
dirsB=%1111111 'défini les ports B en sorties
table 0,(51,50,40,12,6,1)        ;initialisation LCD 4 bits
table 10,("ERREUR")
table 20,("PAS DE SONDE")
table 40,("Temp=      ßC   ")
;*****************************
#macro spin(varw)        ;macro SPIIN
    varw = 0
    for cpt = 1 to 16
        varw=varw * 2 + SO  ;décalage à gauche + SO (0 ou 1) 
        pulsout CLK,1       ;pulse horloge  
    next cpt 
#endmacro
;***********************************
; Initialisation LCD *********
    for cpt=0 to 5
        readtable cpt,car     
        gosub CommInit
    next
;********************
    pause 500
    car=1 : gosub commB        ;raz écran
    car=192 : gosub commB    ;début ligne 2
        for cpt=40 to 56
            readtable cpt,car    ;texte mesure
            gosub dataB
        next    
    high CSB    ;première conversion
    cumul=0
    Do         ;boucle principale
        for cpt2=1 to 5    ;on fait 5 mesures
            do     ;boucle si erreur
                pause 100 
                low CSB            ;lecture registre         
                spin(temptherm)    ;exécution macro 16 premiers bits (poids fort en tête)             
                high CSB           ;nouvelle conversion         
                ;temptherm=%0000011001001100    ;test 100,75 °C             
                ;*****defaut **********************         
                def1=temptherm//2        ;isol bit défaut             
                if def1>0  then            ;erreur détectée
                    gosub erreur
                else
                    if flag=1 then                    ;on est passé par sub erreur
                        car=1 : gosub commB        ;raz écran
                        car=192 : gosub commB    ;début ligne 2
                        for cpt=40 to 56
                            readtable cpt,car        ;on réécrit le texte 
                            gosub dataB
                        next
                        flag=0
                    endif                 
                endif             
            loop while def1>0     ;sortie boucle "erreur" si def1=0
    ;**** temp thermocouple ******************************     
            sig=" "
            temptherm=temptherm/4    ;suppression des 2 derniers bits
            if temptherm>=$2000 then    ;test 1er bit des 14 bits pour valeur négative
                sig="-"
                temptherm = - temptherm  ;idem complément à 2 pour valeur "positive"   
            endif          
            temptherm=temptherm/4    ;suppression des décimales-> val entière
            temptherm=temptherm//4096    ;on garde les 12 derniers bits
            cumul=cumul+temptherm
        next cpt2
        cumul=cumul/5        ;moyenne sur 5 mesures
        bintoascii cumul,b4,b4,b5,b6,b7      
        car=197 :gosub commB
        for cpt= 0 to 4
            lookup cpt,(sig,b4,b5,b6,b7),car
            gosub dataB
        next 
        cumul=0
    loop
; Sub envoi vers LCD parallèle 4 bits *************
Comminit:
    pause 15 ; Delay 15mS
commB:        ; c'est une commande
    rsbit = 0
dataB:        ;c'est une donnée
    pinsB = car & $F0 / 4 | rsbit ; 4 bits poids fort
    pulsout E,1 ; pulse validation sur E
    pinsB = car & $0F * 4 | rsbit ; 4 bits poids faible
    pulsout E,1 ; pulse validation sur E
    rsbit = 1     ; donnée par défaut
    return
;**************************************************
erreur:
    car=1:gosub commB        ;effacement écran
    car=128: gosub commB    ;pos curseur
    for cpt=10 to 15
        readtable cpt,car    ;erreur
        gosub dataB
    next
   car=192 : gosub commB
   for cpt= 20 to 31
        readtable cpt,car        ;pas de sonde
        gosub dataB
    next
   pause 1000
    flag=1
   return
Click to expand...
Bonjour Michel et un grand merci.

Cela fonctionne a merveille et tester dans une bouilloire électrique avec un thermomètre étalon 103° contre Max 31855
99°. c'est très bien .

d'autre part, j'ai reçu le max 6675 et je vais essayer comme sur ton site http://electromag1.wifeo.com/thermocouple-max6675-et-picaxe-08m2.php . afin de comparer les t° d'ébullitions. Et puis en tant que retraité ça me passe le temps.
 
M

MGU

Senior Member
chimere322 said:
Cela fonctionne a merveille et tester dans une bouilloire électrique avec un thermomètre étalon 103° contre Max 31855
99°. c'est très bien .
Click to expand...
Bonjour,
Pour le coup, le MAX31855 est plus proche de la vérité: 100°C, c'est à 1013,25 mb (réel et pas ramené au niveau de la mer), donc, vu la météo, 99°C avec une résolution de 1°C, c'est dans les clous et 103 est certainement au dessus
Le problème que j'ai eu, c'est que avec la casserole sur une plaque à induction, la mesure est fausse, faut la couper pour lire la bonne valeur.
MM
 
C

chimere322

Senior Member
MGU said:
Bonjour,
Pour le coup, le MAX31855 est plus proche de la vérité: 100°C, c'est à 1013,25 mb (réel et pas ramené au niveau de la mer), donc, vu la météo, 99°C avec une résolution de 1°C, c'est dans les clous et 103 est certainement au dessus
Le problème que j'ai eu, c'est que avec la casserole sur une plaque à induction, la mesure est fausse, faut la couper pour lire la bonne valeur.
MM
Click to expand...
Effectivement tout rentre en ligne de compte, ici a 200m d'altitude avec 992mbar en absolue donc compté 22 mbar de plus en relative +une eau très peu calcaire ça correspond. Je vais tester avec le max 6675 car j'ai essayer la sonde sur le max31855 et donc ce n'est pas un problème de thermocouple. Je pense que pour le max6675 c'est dans la conversion .
 
C

chimere322

Senior Member
chimere322 said:
Effectivement tout rentre en ligne de compte, ici a 200m d'altitude avec 992mbar en absolue donc compté 22 mbar de plus en relative +une eau très peu calcaire ça correspond. Je vais tester avec le max 6675 car j'ai essayer la sonde sur le max31855 et donc ce n'est pas un problème de thermocouple. Je pense que pour le max6675 c'est dans la conversion .
Click to expand...
Rebonjour,
alors voila, test fait avec MAX 6675 comme sur ton site avec 08M2 et afficheur 1602 série et ton programme. Température 97° dans les mêmes conditions. Sur mon four a chaleur tournantes, les gars de chez Thomson(pas con les mecs) ont prévus un trou de 4.8mm a l'opposé du ventilo à mis chemin entre les résistances de sol et de gril.Maintenant j'ai toutes les options annoncées.Y'a plus qu'a installer. Merci a tous les participants. Je considère le sujet comme clos et qui servira à d'autre picaxien.
 
M

MGU

Senior Member
chimere322 said:
Rebonjour,
alors voila, test fait avec MAX 6675 comme sur ton site avec 08M2 et afficheur 1602 série et ton programme. Température 97° dans les mêmes conditions. Sur mon four a chaleur tournantes, les gars de chez Thomson(pas con les mecs) ont prévus un trou de 4.8mm a l'opposé du ventilo à mis chemin entre les résistances de sol et de gril.Maintenant j'ai toutes les options annoncées.Y'a plus qu'a installer. Merci a tous les participants. Je considère le sujet comme clos et qui servira à d'autre picaxien.
Click to expand...
Bonjour,
Bon bricolage...
Et si tu veux aller un peu plus loin, on peut envisager un thermostat électronique simple, avec affichage de la t° de consigne (potentiomètre) et une régulation TOR genre +/- 2 ou 3 degrés avec relais statique. Je ne connais pas la fourchette de régulation d'un système à bulbe.
Pour info, le programme MAX31855 fait une moyenne sur 5 mesures pour améliorer la stabilité.
MM
 
C

chimere322

Senior Member
MGU said:
Bonjour,
Bon bricolage...
Et si tu veux aller un peu plus loin, on peut envisager un thermostat électronique simple, avec affichage de la t° de consigne (potentiomètre) et une régulation TOR genre +/- 2 ou 3 degrés avec relais statique. Je ne connais pas la fourchette de régulation d'un système à bulbe.
Pour info, le programme MAX31855 fait une moyenne sur 5 mesures pour améliorer la stabilité.
MM
Click to expand...
Hello Michel,l'idée est alléchante,
Je dispose d'un autre four en panne mis de coté avec le même thermostat que j'avais acheté : https://www.amazon.fr/dp/B0BH5BDZY8?psc=1&ref=ppx_pop_dt_b_product_details. Pour aller plus loin,je suis partant aussi avec un lcd 1602 série ou pourquoi pas avec un Max 6219 5 digits le tout mis dans un boitier . Cela demanderas un peu de mécanique et recâbler dans le four, mais c'est très intéressant et instructif pour la programmation. Alors allons y gaiement.
Je te souhaite un bon weekend .
 
M

MGU

Senior Member
Hello,
Tu parles de LCD série, avec quel adaptateur? I2C ou RS232 ?
Le 14M2 était nécessaire pour un LCD parallèle (il faut 6 broches µC). Pour un LCD série RS232, une suffit et en I2C c'est 2.
et le MAX 7219, c'est 3, comme le TM1637.
Bref, le plus simple et pratique, c'est le LCD série picaxe, on écrit ce qu'on veut où on veut.
Penser aussi à un relais statique 25A commande 5V...par ex: https://fr.aliexpress.com/item/1005006885250806.html?spm=a2g0o.detail.pcDetailTopMoreOtherSeller.4.715eHDz9HDz9C2&gps-id=pcDetailTopMoreOtherSeller&scm=1007.40000.327270.0&scm_id=1007.40000.327270.0&scm-url=1007.40000.327270.0&pvid=a9b208dc-bd73-4d7a-a503-4d16195e527a&_t=gps-id:pcDetailTopMoreOtherSeller,scm-url:1007.40000.327270.0,pvid:a9b208dc-bd73-4d7a-a503-4d16195e527a,tpp_buckets:668#2846#8107#1934&pdp_npi=4@dis!EUR!3.63!0.99!!!27.70!7.58!@211b801617184697091103183eaada!12000038617522492!rec!FR!2679328060!AC&utparam-url=scene:pcDetailTopMoreOtherSeller|query_from:&search_p4p_id=202406150941491585200978200870582066_3
MM
 
Last edited:
C

chimere322

Senior Member
Hello,
Aucun soucis pour le lcd Picaxe, j'ai des axes 133Y et j'ai commandé 2 relais statiques 25A , un pour la sol et un pour le gril, il va falloir que je mette aussi une alim 5V DC. Sur le four, je conserve le commutateur M/A et le Commutateur sol,gril ou les deux.
 
M

MGU

Senior Member
chimere322 said:
Hello,
Aucun soucis pour le lcd Picaxe, j'ai des axes 133Y et j'ai commandé 2 relais statiques 25A , un pour la sol et un pour le gril, il va falloir que je mette aussi une alim 5V DC. Sur le four, je conserve le commutateur M/A et le Commutateur sol,gril ou les deux.
Click to expand...
Hello,
Il y a une minuterie?
MM
 
C

chimere322

Senior Member
MGU said:
Hello,
Il y a une minuterie?
MM
Click to expand...
Oui c'est une minuterie mécanique jusqu’à 120Mn et qui coupe tous à zéro. Donc pas d'horloge avec affichage horaire.
Je pense que suivant ton idée le schéma vas être parfait pour faire un circuit sur tci4 ou diptrace. Un peu de boulot en perspective mais vu les temps morose que l'on a ce ne sera pas désagréable pour passé des après midi dans le labo (dans mon atelier). Et puis c'est bon pour mes vieux neurones. Chose importante que je n'ai pas précisé, dans ces fours il n'y a pas de transfo, tous est sur secteur 230V. Si il faut des composants en plus, aucun soucis. Voila Michel.
 
Last edited:
M

MGU

Senior Member
Pour l'alim, quelques bricoles à placer sur le PCB:
www.gotronic.fr

Transfo moulé 44157

Transformateur surmoulé 1 secondaire à picots pour CI. Tension primaire: 230 Vac. Tension secondaire (Un): 1 x 6 Vac Tension à vide: 10,5 Vac Puissance: 2,3 VA Dimensions: 32 x 27 x 30 mm. Isolation primaire/secondaire: 4000 V.
www.gotronic.fr www.gotronic.fr
www.gotronic.fr

78L05

www.gotronic.fr www.gotronic.fr
www.gotronic.fr

PB80D

www.gotronic.fr www.gotronic.fr
https://www.gotronic.fr/art-condensateur-radial-100uf-25v-11348.htm...(un ou deux)
www.gotronic.fr

Condensateur multicouches 100 nF

Condensateur céramique multicouches. Pas: 5.08 mm. Tension de service: 50 Vcc. Photo non contractuelle. La couleur et la forme peuvent varier suivant les approvisionnements.
www.gotronic.fr www.gotronic.fr
Il faut un seul relais, le commutateur est derrière.
MM
 
C

chimere322

Senior Member
MGU said:
Pour l'alim, quelques bricoles à placer sur le PCB:
www.gotronic.fr

Transfo moulé 44157

Transformateur surmoulé 1 secondaire à picots pour CI. Tension primaire: 230 Vac. Tension secondaire (Un): 1 x 6 Vac Tension à vide: 10,5 Vac Puissance: 2,3 VA Dimensions: 32 x 27 x 30 mm. Isolation primaire/secondaire: 4000 V.
www.gotronic.fr www.gotronic.fr
www.gotronic.fr

78L05

www.gotronic.fr www.gotronic.fr
www.gotronic.fr

PB80D

www.gotronic.fr www.gotronic.fr
https://www.gotronic.fr/art-condensateur-radial-100uf-25v-11348.htm...(un ou deux)
www.gotronic.fr

Condensateur multicouches 100 nF

Condensateur céramique multicouches. Pas: 5.08 mm. Tension de service: 50 Vcc. Photo non contractuelle. La couleur et la forme peuvent varier suivant les approvisionnements.
www.gotronic.fr www.gotronic.fr
Il faut un seul relais, le commutateur est derrière.
MM
Click to expand...
J'ai tous les composants en stocks dans mes casiers. Et par dessus tout je te souhaite a tout hasard une bonne fête des pères. Ci je te dis ça c'est parce que ma fille unique vient de me la souhaitée alors que pour moi c'est à des années lumières. Je te souhaite un bon dimanche. A suivre.
 
M

MGU

Senior Member
Meri
chimere322 said:
J'ai tous les composants en stocks dans mes casiers. Et par dessus tout je te souhaite a tout hasard une bonne fête des pères. Ci je te dis ça c'est parce que ma fille unique vient de me la souhaitée alors que pour moi c'est à des années lumières. Je te souhaite un bon dimanche. A suivre.
Click to expand...
Merci, et bon dimanche à toi et ta famille.
MM
 
M

MGU

Senior Member
Mais faudra quand même tester sur maquette avant tout. J'ai encore rien tester.
Le code: La led s'allume pendant l'alim du four
Code: 
;régulation four MM 160624
;
#picaxe 14M2
#no_data
symbol LCD=B.1
symbol CLK=C.1           ; pulse horloge
symbol CSB=C.2       ;demande lecture  _____/
symbol SO=pinC.3     ;bit de donnée serial out
symbol potar=C.4        ;potentiomètre consigne
symbol four=B.4
symbol led=B.5
symbol def1=bit0        ;bit défaut
symbol flag=bit1        ;passage par défaut
symbol cpt=b1            ;compteur
symbol cpt2=b2            ;compteur
symbol delta=b3        ;écart limites / consigne: régulation TOR
symbol cons=b4        ;ici,0 à 255
   ;b5,b6,b7  chiffres affichage
symbol varw=w13         ;var temporaire
symbol limit=w12        ;tempé interne
symbol temptherm=w11    ;tempé thermocouple
symbol temp=w10  
setfreq M4               
symbol baud=N2400_4
;*****************************
;La broche SO va copier successivement la valeur de chaque bit du registre.
#macro spin(varw)        ;macro SPIIN
    varw = 0           
    for cpt = 1 to 16   
      varw=varw * 2 + SO       ;décalage à gauche + SO (0 ou 1)   
      pulsout CLK,1            ;pulse horloge    
    next cpt   
#endmacro
;************************************
    pause 500
    gosub texte
    high CSB    ;première conversion
    temp=0
    delta=2        ;plage de température : +/- delta
   Do             ;boucle principale
        gosub affcon
        gosub lectherm
        gosub afftherm
    loop
lectherm:
    temp=0   
    ;readadc B.2,temp    ;simu
    ;return                ;simu
    for cpt2=1 to 5
        do
            pause 100   
            low CSB            ;lecture registre           
            spin(temptherm)    ;exécution macro 16 premiers bits (poid fort en tête          
            high CSB                ;nouvelle conversion
;temptherm=%0000011001001100    ;test 100,75 °C
;*****defaut **********************          
            def1=temptherm//2        ;isol bit défaut
            if def1>0  then        ;y a un défaut                   
                gosub erreur               
            endif
        loop while def1>0         ;y a plus de défaut
        if flag=1 then
            gosub texte                ;on réécrit le texte
            flag=0
        endif
    ;**** temp thermocouple ******************************
        temptherm=temptherm/4    ;suppression des 2 derniers bits
        if temptherm>=$2000 then    ;test 1er bit des 14 bits pour valeur négative
            temptherm=0                ;valeur négatives non traitées :valeur mini à 0
        endif
        temptherm=temptherm/4    ;suppression des décimales-> val entière
        temptherm=temptherm//4096    ;on garde les 12 derniers bits
        temp=temp+temptherm        ;cumul sur 5 valeurs
    next cpt2
    temp=temp/5
    return
afftherm:
    bintoascii temp,b5,b5,b5,b6,b7       
    if temp<100 then: b5=" " :endif        ;suppression des 0 non significatifs
    if temp<10 then :b6=" " :endif
    serout LCD,baud,(254,202,b5,b6,b7)
    limit= temp+delta     ;limite sup
    if cons>limit then
        high four,led
    endif
    if temp>delta then    ;éviter valeur négatives
        limit=temp-delta
    endif
    if cons<limit then
        low four,led
    endif   
    return
affcon:
    readadc potar,cons        ;lecture potar consigne
    bintoascii cons,b5,b6,b7           
    if cons<100 then: b5=" " :endif
    if cons<10 then :b6=" " :endif
    serout LCD,baud,(254,138,b5,b6,b7)   
    return

texte:
    serout LCD,baud,(254,128,"CONSIGNE :    ßC")
    serout LCD,baud,(254,192,"TEMP LUE :    ßC") 
    return
erreur:
    serout LCD,baud, (254,1,254,128,"     ERREUR")
    serout LCD,baud, (254,194,"PAS DE SONDE")       
    pause 1000
    flag=1
    return
 
Last edited:
C

chimere322

Senior Member
Hello Michel, tous cela m'a l’air bien parti. Pour le fusible de protection, fusible rapide ou temporisé?
En attendant la commande gotronic ,je vais tenté une approche d'implantation avec diptrace, je connais déjà les dimensions du circuit a implanter 60x180 donc beaucoup de marge. Je ne me suis jamais servi de Diptrace mais qui peu le plus peu le moins. De plus j'ai tout ce qu'il faut pour la gravure en abondance.
 
M

MGU

Senior Member
Rapide ou temporisé? Bof, peu importe à mon avis, si il le faut, il fondra de toute façon.

Je viens de faire un essai, la sonde à vis a beaucoup d'inertie et l'affichage de la consigne aussi. Je vois déjà deux petites modifs du code:
Monter la fréquence du picaxe de 4 à 16 MHz et une moyenne sur 10 mesures
Code: 
setfreq M16             
symbol baud=N2400_16
Et une moyenne de température sur 10 mesures au lieu de 5
for cpt2=1 to 10
et : temp=temp/10

DipTrace demande une petite prise en main. Il faut installer le patch français. En cas de pb, on en reparle, mais je ne suis pas du tout un expert.
MM
 
Last edited:
C

chimere322

Senior Member
MGU said:
Rapide ou temporisé? Bof, peu importe à mon avis, si il le faut, il fondra de toute façon.

Je viens de faire un essai, la sonde à vis a beaucoup d'inertie et l'affichage de la consigne aussi. Je vois déjà deux petites modifs du code:
Monter la fréquence du picaxe de 4 à 16 MHz et une moyenne sur 10 mesures
Code: 
setfreq M16            
symbol baud=N2400_16
Et une moyenne de température sur 10 mesures au lieu de 5
for cpt2=1 to 10
et : temp=temp/10

DipTrace demande une petite prise en main. Il faut installer le patch français. En cas de pb, on en reparle, mais je ne suis pas du tout un expert.
MM
Click to expand...
Ok pour 16 MHz , au sujet de Diptrace si c'est complexe alors passerai à TCI 4.4 et je vais essayer de faire des empreintes grâce aux datasheet. Touchons du bois. Merci Michel pour ton temps et investissements.
 
You must log in or register to reply here.
Top